linit.F

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file linit.F

C **********************************************************************


      SUBROUTINE linit(LFILE,LEPIN,PLZ,PPZ,INTER)

      IMPLICIT NONE
      
C...Initialize for an incoming lepton (type LEPIN, momentum pz=PLZ)
C...and target nucleon (momentum pz=PPZ) to interact via INTER.
C...Find maximum of differential cross section, calculate QCD event
C...probabilities or read them from logical file LFILE (if >0).
C...Numerical integration to obtain total cross-section.

      COMMON /lintrl/ psave(3,4,5),ksave(4),xmin,xmax,ymin,ymax,
     &q2min,q2max,w2min,w2max,ilep,inu,ig,iz
      REAL psave,xmin,xmax,ymin,ymax,q2min,q2max,w2min,w2max
      INTEGER ksave,ilep,inu,ig,iz
      SAVE /lintrl/

*
* to avoid variable conflictions, a second keep element is necessary
* with the same common block name (see LPTOU2)
*
      COMMON /leptou/ cut(14),lst(40),parl(30),
     &                x,y,w2,q2,u
      REAL cut,parl,x,y,w2,q2,u
      INTEGER lst
      SAVE /leptou/

      COMMON /linter/ pari(50),ewqc(2,2,8),qc(8),zl(2,4),zq(2,8),pq(17)
      REAL  pari,ewqc,qc,zl,zq,pq
      SAVE /linter/

      COMMON /lgrid/ nxx,nww,xx(31),ww(21),pqg(31,21,3),pqqb(31,21,2), 
     &qgmax(31,21,3),qqbmax(31,21,2),ycut(31,21),xtot(31,21),np
      REAL    xx,ww,pqg,pqqb,qgmax,qqbmax,ycut,xtot
      INTEGER nxx,nww,np
      SAVE /lgrid/


      COMMON /loptim/ optx(4),opty(4),optq2(4),optw2(4),comfac
      REAL optx,opty,optq2,optw2,comfac
      SAVE /loptim/

      INTEGER  nlupdm,nplbuf
      parameter(nlupdm=4000,nplbuf=5)
      common/lujets/n,k(nlupdm,5),p(nlupdm,nplbuf),v(nlupdm,5)
      INTEGER  n,k
      REAL  p,v
      SAVE /lujets/

      common/ludat1/mstu(200),paru(200),mstj(200),parj(200)
      INTEGER  mstu,mstj
      REAL  paru,parj
      SAVE /ludat1/

      common/ludat2/kchg(500,3),pmas(500,4),parf(2000),vckm(4,4)
      INTEGER  kchg
      REAL  pmas,parf,vckm
      SAVE /ludat2/

      COMMON /lboost/ dbeta(2,3),stheta(2),sphi(2),pb(5),phir
      DOUBLE PRECISION dbeta
      REAL stheta,sphi,pb,phir
      SAVE /lboost/

      COMMON /lminui/ xkin(4),ukin(4),wkin(4),ain(4),bin(4),
     &maxfin,relup,relerr,reler2,fcnmax
      REAL xkin,ukin,wkin,ain,bin,relerr,relup,reler2,fcnmax
      INTEGER maxfin
      SAVE /lminui/

      COMMON /lminuc/ namkin(4),nam(30)
      CHARACTER*10 namkin,nam
      SAVE /lminuc/

      COMMON /lpflag/ lst3
      INTEGER lst3
      SAVE /lpflag/

      COMMON /pypara/ ipy(80),pypar(80),pyvar(80)
      REAL pypar,pyvar
      INTEGER ipy
      SAVE /pypara/ 

      common/pypars/mstp(200),parp(200),msti(200),paripy(200) 
      INTEGER mstp,msti
      REAL parp,paripy
      SAVE /pypars/

      INTEGER imxpdf
      parameter(imxpdf=40)
      COMMON /pepadm/cpdfnam(2,imxpdf),ipdfnam(2,imxpdf),
     &       iplst(10),cunpol,cpol
      CHARACTER*256 cpdfnam,cunpol,cpol
      INTEGER iplst,ipdfnam
      SAVE /pepadm/

      common/maxfromhand/ fmaxfh
      REAL fmaxfh
      SAVE/maxfromhand/

      INTEGER inter,lfile,lepin,ncall,i,j,ifl
      REAL plz,ppz,pi,pm2,roots
      REAL ulmass,ulangl,umin,umax,s
      INTEGER lqcd,ltm,ipmax,ip,iw,ix
      REAL ti1,ti2

      INTEGER lstw(40)
      REAL parlw(30)
      DATA pi/3.1415927/,ncall/0/

*PEPSI>>
      external leptod   ! MB, 15-Nov-2002, Load default PDF names

      DO i=1,imxpdf
      IF(lst(15).eq.ipdfnam(1,i)) THEN
         cunpol=cpdfnam(1,ipdfnam(2,i))
         cpol  =cpdfnam(2,ipdfnam(2,i))
      ENDIF
      ENDDO

      IF (lst(15).EQ.150) CALL  setctq5(3) 
      IF (lst(15).EQ.151) CALL  setctq5(1) 
      IF (lst(15).EQ.152) CALL  setctq5(8) 
      IF (lst(15).EQ.173) CALL  setctq6(1)
      IF (lst(15).EQ.174) CALL  setctq6(2)
      IF (lst(15).EQ.175) CALL  setctq6(3)
      CALL pollinit(lfile,lepin,plz,ppz,inter)
      IF (lst(40).NE.0) RETURN
*PEPSI<<       

      ncall=ncall+1
      lst3=lst(3)
      IF(lst(18).GE.1) THEN
C...W, Z masses from theta-Weinberg, Fermi constant GF and rad. corr.
        pmas(24,1)=sqrt(pi*parl(16)/(sqrt(2.)*parl(17)*parl(5)*
     &  (1.-parl(18))))
        pmas(23,1)=pmas(24,1)/sqrt(1.-parl(5))
      ENDIF
C...Couplings between Z0 and left/right-handed leptons and quarks.
      zl(1,1)=-.5+parl(5)
      zl(1,2)=parl(5)
      zl(2,1)=zl(1,2)
      zl(2,2)=zl(1,1)
      zl(1,3)=0.5
      zl(2,3)=0.
      zl(1,4)=0.
      zl(2,4)=0.5
      DO 10 ifl=1,8
      zq(1,ifl)=sign(0.5,qc(ifl))-qc(ifl)*parl(5)
   10 zq(2,ifl)=-qc(ifl)*parl(5)

C...Set initial state.
      lst(23)=inter
      ksave(1)=lepin
      ksave(2)=2212
      k(1,1)=21
      k(1,2)=ksave(1)
      k(1,3)=0
      k(1,4)=0
      k(1,5)=0
      k(2,1)=21
      k(2,2)=ksave(2)
      k(2,3)=0
      k(2,4)=0
      k(2,5)=0
      p(1,1)=0.
      p(1,2)=0.
      p(1,3)=plz
      p(1,5)=ulmass(ksave(1))
      p(1,4)=sqrt(p(1,3)**2+p(1,5)**2)
      p(2,1)=0.
      p(2,2)=0.
      p(2,3)=ppz
      p(2,5)=ulmass(ksave(2))
      p(2,4)=sqrt(p(2,3)**2+p(2,5)**2)
      n=2
      lst(28)=3
C...Save momentum vectors of incoming particles
      DO 20 i=1,2
      DO 20 j=1,5
   20 psave(3,i,j)=p(i,j)
C...Dot-product of initial particles, cms energy
      parl(21)=2.*(dble(p(1,4))*dble(p(2,4))-dble(p(1,3))*dble(p(2,3)))
      roots=sqrt((dble(p(1,4))+dble(p(2,4)))**2
     &          -(dble(p(1,3))+dble(p(2,3)))**2)
      IF(lst(3).GE.4.OR.(lst(3).EQ.3.AND.ncall.EQ.1)) WRITE(6,1000)
     &lepin,(p(1,j),j=1,3),parl(1),parl(2),(p(2,j),j=1,3),inter,roots
      write(*,*) 'INTER,ROOT',inter,roots
      IF(plz*ppz.GT.0.1) THEN
        WRITE(6,1010)
        stop
      ENDIF

C...Reduced header for Jetset/Pythia
      mstu(12)=0
      mstp(122)=0
      IF(lst(3).GE.4.OR.(lst(3).EQ.3.AND.ncall.EQ.1)) 
     &WRITE(6,1020) mstu(181),mstu(182),mstp(181),mstp(182)
C...If JETSET version before 7.402, problem with azimuthal dependence
C...in LUSHOW solved by chosing flat azimuthal dependence.
      IF(mstu(181).LE.7.AND.mstu(182).LT.402) THEN
        mstj(46)=0
        WRITE(6,1030) mstj(46)
      ENDIF
C...Initialize PYTHIA for parton densities.
      IF(lst(15).GT.0) THEN
C...Set switches and parameters for parton densities in PYSTFU.
        mstp(51)=lst(15)
        mstp(52)=lst(16)
        mstp(58)=lst(12)
      ENDIF

      write(*,*) 'PYINIT not included !'
*HI      CALL PYINIT('NONE','e-','p',ROOTS)      



      parl(26)=parp(1)
CAE--     use Lambda from parton densities in initial cascade
      pypar(21)=parp(1)
C...Reset PYTHIA 4.8 parameters from LEPTO parameters.
      IF(mod(lst(8),10).EQ.3.OR.mod(lst(8),10).EQ.5) ipy(13)=0
      IF(lst(35).NE.1.AND.
     &(mod(lst(8),10).EQ.4.OR.mod(lst(8),10).EQ.5)) ipy(14)=0
      ipy(8)=lst(12)

      IF(psave(3,1,3).LT.0.) THEN
C...Flip event to have initial lepton along +z axis
        p(1,3)=-p(1,3)
        p(2,3)=-p(2,3)
      ENDIF
C...Boost parameters to cms of incoming particles
      dbeta(1,1)=0.d0
      dbeta(1,2)=0.d0
      dbeta(1,3)=(dble(p(1,3))+dble(p(2,3)))/(dble(p(1,4))+dble(p(2,4)))
      sphi(1)=0.d0
      stheta(1)=0.d0
      IF(lst(17).NE.0) THEN
C...For varying beam energies, transform to cms, lepton along +z axis.
        CALL ludbrb(0,0,0.,0.,0.d0,0.d0,-dbeta(1,3))
        sphi(1)=ulangl(p(1,1),p(1,2))
        CALL ludbrb(0,0,0.,-sphi(1),0.d0,0.d0,0.d0)
        stheta(1)=ulangl(p(1,3),p(1,1))
        CALL ludbrb(0,0,-stheta(1),0.,0.d0,0.d0,0.d0)
        lst(28)=2
      ENDIF

C...Effective limits on kinematic variables x, y, Q**2, W**2
      pm2=p(2,5)**2
      s=parl(21)
      xmin=max(cut(1),0.)
      xmax=min(cut(2),1.)
      ymin=max(cut(3),0.)
      ymax=min(cut(4),1.)
      q2min=max(cut(5),0.)
      q2max=min(cut(6),s)
      w2min=max(cut(7),0.)
      w2max=min(cut(8),s+pm2)
      umin=max(cut(9),0.)
      umax=min(cut(10),s/(2.*p(2,5)))
      DO 40 i=1,2
      xmin=max(xmin,q2min/(s*ymax),q2min/(2.*p(2,5)*umax),
     &1.-(w2max-pm2)/max(s*ymin,1.e-22),
     &1.-(w2max-pm2)/max(2.*p(2,5)*umin,1.e-22))
      xmax=min(xmax,q2max/max(s*ymin,1.e-22),
     &q2max/max(2.*p(2,5)*umin,1.e-22),
     &1.-(w2min-pm2)/(s*ymax),1.-(w2min-pm2)/(2.*p(2,5)*umax))
      ymin=max(ymin,q2min/(s*xmax),(w2min-pm2)/(s*(1.-xmin)),
     &(w2min-pm2+q2min)/s,2.*p(2,5)*umin/s)
      ymax=min(ymax,q2max/max(s*xmin,1.e-22),
     &(w2max-pm2)/max(s*(1.-xmax),1.e-22),
     &(w2max-pm2+q2max)/s,2.*p(2,5)*umax/s)
      q2min=max(q2min,s*xmin*ymin,s*ymin-w2max+pm2,
     &2.*p(2,5)*umin*xmin,(w2min-pm2)*xmin/(1.-xmin))
      q2max=min(q2max,s*xmax*ymax,s*ymax-w2min+pm2,
     &2.*p(2,5)*umax*xmax,(w2max-pm2)*xmax/max(1.-xmax,1.e-22))
      w2min=max(w2min,s*(1.-xmax)*ymin+pm2,q2min*(1.-xmax)/xmax+pm2,
     &s*ymin-q2max+pm2,2.*p(2,5)*umin*(1.-xmax)+pm2)
      w2max=min(w2max,s*(1.-xmin)*ymax+pm2,
     &q2max*(1.-xmin)/max(xmin,1.e-22)+pm2,
     &s*ymax-q2min+pm2,2.*p(2,5)*umax*(1.-xmin)+pm2)
C     UMIN=MAX(UMIN,....)
C     UMAX=MIN(UMAX,....)
   40 CONTINUE
      IF(lst(3).GE.4.OR.(lst(3).EQ.3.AND.ncall.EQ.1)) WRITE(6,1050)
     &cut,xmin,xmax,ymin,ymax,q2min,q2max,w2min,w2max,umin,umax
      IF(xmax.LT.xmin.OR.ymax.LT.ymin.OR.q2max.LT.q2min.OR.
     &w2max.LT.w2min) THEN
        IF(lst(3).GE.1) WRITE(6,1100)
        IF(lst(3).GE.2) THEN
          WRITE(6,1900)
          stop
        ENDIF
      ENDIF
      IF(xmin.LT.1.e-10.OR.q2min.LT.1.e-01) THEN
        IF(lst(3).GE.1) WRITE(6,1110)
        IF(lst(3).GE.2) THEN
          WRITE(6,1900)
          stop
        ENDIF
      ENDIF

      pari(11)=(parl(1)-parl(2))/parl(1)
      ksave(4)=lepin
      ilep=1
      IF(lepin.LT.0) ilep=2
      inu=0
      IF(iabs(lepin).EQ.12.OR.iabs(lepin).EQ.14
     &.OR.iabs(lepin).EQ.16) inu=1
      IF(inu.EQ.1) THEN
C...Set full polarisation for incoming neutrino.
        parl(6)=-1.
        IF(lepin.LT.0) parl(6)=1.
      ENDIF
      IF(lst(23).EQ.1.AND.inu.EQ.0) THEN
C...Electromagnetic interaction.
        ksave(3)=22
        ig=1
        iz=0
      ELSEIF(lst(23).EQ.2) THEN
C...Weak charged current, only one helicity state contributes.
        IF(ksave(1).LT.0.AND.parl(6).LT.-0.99
     &  .OR.ksave(1).GT.0.AND.parl(6).GT.0.99) THEN
          IF(lst(3).GE.1) WRITE(6,1150) lepin,parl(6)
          IF(lst(3).GE.2) THEN
            WRITE(6,1900)
            stop
          ENDIF
        ENDIF
        IF(mod(iabs(lepin),2).EQ.0) THEN
          ksave(3)=isign(24,lepin)
          ksave(4)=isign(iabs(lepin)-1,lepin)
        ELSE
          ksave(3)=isign(24,-lepin)
          ksave(4)=isign(iabs(lepin)+1,lepin)
        ENDIF
      ELSEIF(lst(23).EQ.3.OR.(lst(23).EQ.4.AND.inu.EQ.1)) THEN
C...Weak neutral current.
        ksave(3)=23
        ig=0
        iz=1
      ELSEIF(lst(23).EQ.4.AND.inu.EQ.0) THEN
C...Neutral current, electromagnetic and weak with interference.
        ksave(3)=23
        ig=1
        iz=1
      ELSE
        IF(lst(3).GE.1) WRITE(6,1200) inter,lepin
        IF(lst(3).GE.2) THEN
          WRITE(6,1900)
          stop
        ENDIF
      ENDIF

C...Choice of independent variables.
      IF(lst(1).EQ.0) THEN
        lst(31)=1
        IF(inter.EQ.2.OR.inter.EQ.3) lst(31)=2
      ELSE
        lst(31)=iabs(lst(1))
      ENDIF
      IF(lst(31).LT.1.OR.lst(31).GT.3) THEN
        IF(lst(3).GE.1) WRITE(6,1210) lst(1),lst(31)
        IF(lst(3).GE.2) THEN
          WRITE(6,1900)
          stop
        ENDIF
      ENDIF
      IF(lst(1).LT.0) THEN
C...User-defined optimization parameters.
        IF(lst(3).GE.4.OR.(lst(3).EQ.3.AND.ncall.EQ.1))
     &  WRITE(6,1220) optx,opty,optq2,optw2
      ELSE
C...Set optimization parameters.
        DO 50 i=1,4
        optx(i)=0.
        opty(i)=0.
        optq2(i)=0.
   50   optw2(i)=0.
        IF(inter.EQ.1) THEN
          optx(2)=1.
          opty(1)=1.
          optq2(3)=1.
          optw2(3)=1.
        ELSEIF(inter.EQ.4) THEN
          optx(1)=0.1
          optx(2)=1.
          opty(1)=1.
          optq2(1)=0.5
          optq2(2)=0.5
          optq2(3)=1.
          optw2(1)=0.5
          optw2(2)=0.5
          optw2(3)=1.
        ELSE
          optx(1)=1.
          opty(1)=1.
          optq2(1)=1.
          optw2(1)=1.
        ENDIF
      ENDIF

C...Initialize Monte Carlo estimate of cross section.
      parl(24)=0.
      pari(27)=0.
      pari(28)=0.
      pari(29)=0.
      pari(30)=0.
      pari(32)=0.
      IF(lst(23).EQ.2) THEN
C...Constant factor GF**2/pi for CC, transformation to picobarn.
        pari(31)=parl(17)**2/pi*0.39e+09
      ELSE
C...Constant factor 2*pi*alpha**2 for NC, transformation to picobarn.
        pari(31)=2.*pi*parl(16)**2*0.39e+09
      ENDIF
      IF(lst(3).GE.4.OR.(lst(3).EQ.3.AND.ncall.EQ.1))
     &WRITE(6,1250) (i,lst(i),lst(i+10),parl(i),parl(i+10),i=1,10)

C...Set up grid with longitudinal structure function, QCD & target mass;
C...only when photon exchange is included
      lqcd=mod(lst(11),10)
      ltm=mod(lst(11)/10,10)
      IF(lst(11).NE.0.AND.(inter.EQ.1.OR.inter.EQ.4)) CALL fltabl

C...Get integrated cross-section.
      parl(23)=0.
      IF(lst(10).GT.0) CALL lxsect
      IF(lqcd.EQ.2.OR.ltm.EQ.2) THEN
        WRITE(6,1300)
        IF(lqcd.EQ.2) WRITE(6,1310)
        IF(ltm .EQ.2) WRITE(6,1320)
        WRITE(6,1330)
      ENDIF

      IF(lst(2).EQ.1) THEN
C...Find max value of differential cross section for rejection.
        ukin(1)=(xmax+xmin)/2.
        wkin(1)=0.8*(xmax-xmin)/2.
        ain(1)=xmin
        bin(1)=xmax
        IF(lst(31).EQ.1) THEN
          ukin(2)=(q2max+q2min)/2.
          wkin(2)=0.8*(q2max-q2min)/2.
          ain(2)=q2min
          bin(2)=q2max
          namkin(2)='      Q**2'
        ELSEIF(lst(31).EQ.2) THEN
          ukin(2)=(ymax+ymin)/2.
          wkin(2)=0.8*(ymax-ymin)/2.
          ain(2)=ymin
          bin(2)=ymax
          namkin(2)='         y'
        ELSEIF(lst(31).EQ.3) THEN
          ukin(2)=(w2max+w2min)/2.
          wkin(2)=0.8*(w2max-w2min)/2.
          ain(2)=w2min
          bin(2)=w2max
          namkin(2)='      W**2'
        ENDIF
C...Maximum obtained by minimizing -(diff. x-section).
        CALL ltimex(ti1)
        CALL lminew
        CALL ltimex(ti2)
        pari(lst(23))=fcnmax*1.1
CMM.. Maximum inserted by hand if MINUIT fails
        IF(pari(lst(23)).EQ.0.0) pari(lst(23))=fmaxfh
        IF(lst(3).GE.4.OR.(lst(3).EQ.3.AND.ncall.EQ.1))
     &  WRITE(6,1400) pari(lst(23)),ti2-ti1
      ENDIF

      IF(lfile.GT.0.AND.lst(19).GE.0) THEN
C...Read QCD weights from file.
        READ(lfile) lstw,parlw,nxx,nww,np,xx,ww
        ipmax=2
        IF(lstw(17).NE.0) ipmax=3
        READ(lfile) (((pqg(ix,iw,ip),ix=1,nxx),iw=1,nww),ip=1,np),
     &  (((pqqb(ix,iw,ip),ix=1,nxx),iw=1,nww),ip=1,np),
     &  (((qgmax(ix,iw,ip),ix=1,nxx),iw=1,nww),ip=1,ipmax),
     &  (((qqbmax(ix,iw,ip),ix=1,nxx),iw=1,nww),ip=1,min(2,ipmax)),
     &  ycut
        IF(np.NE.1) READ(lfile) xtot
        CLOSE(lfile)
C...Reset parameters for matrix element integration.
        parl(8)=parlw(8)
        parl(9)=parlw(9)
        parl(11)=parlw(11)
        parl(12)=parlw(12)
        parl(13)=parlw(13)
C...Check current parameter values against those used when
C...calculating weights.
        IF(lst(12).NE.lstw(12).OR.lst(13).NE.lstw(13)
     &  .OR.lst(15).NE.lstw(15).OR.lst(16).NE.lstw(16)
     &  .OR.lst(17).NE.lstw(17).OR.lst(23).NE.lstw(23)
     &  .OR.abs(parl(1)-parlw(1)).GT.0.1.OR.abs(parl(2)-parlw(2)).GT.0.1
     &  .OR.abs(parl(5)-parlw(5)).GT.0.01
     &  .OR.abs(parl(6)-parlw(6)).GT.0.1) THEN
         IF(lst(3).GE.1)
     &    WRITE(6,1500) lst(12),lstw(12),lst(13),lstw(13),lst(15),
     &    lstw(15),lst(16),lstw(16),lst(17),lstw(17),lst(23),lstw(23),
     &    parl(1),parlw(1),parl(2),parlw(2),parl(5),parlw(5),parl(6),
     &    parlw(6)
          IF(lst(3).GE.2) THEN
            WRITE(6,1900)
            stop
          ENDIF
        ENDIF
      ELSEIF((lst(19).GE.0.OR.lst(19).EQ.-10).AND.
     &(lst(8).EQ.1.OR.lst(8)/10.EQ.1.OR.mod(lst(8),10).EQ.9)) THEN
C...Calculate weights if 1st order QCD from grid is requested.
        CALL ltimex(ti1)
        CALL lweits(lfile)
        CALL ltimex(ti2)
        IF(lst(3).GE.4.OR.(lst(3).EQ.3.AND.ncall.EQ.1))
     &  WRITE(6,1510) ti2-ti1
      ENDIF

C...Reset counters to zero for Monte Carlo estimate of cross section.
      pari(27)=0.
      pari(28)=0.
      pari(29)=0.
      pari(30)=0.
      lst(32)=0
      RETURN

 1000 FORMAT(' ',68('='),//,
     &'A MONTE CARLO GENERATOR FOR DEEP INELASTIC LEPTON-'
     &,'NUCLEON SCATTERING',//,
     &'LEPTO version 6.5, April 20, 1996',/,68('='),//,
     &'Lepton: type =',i3,5x,'momentum (px,py,pz) =',3f8.1,
     &' GeV',//,'Target: A, Z =',2f3.0,2x,
     &'momentum (px,py,pz) =',3f8.1,' GeV',//,
     &'Interaction :',i3,14x,' CMS energy =',1pg12.4,' GeV',/68('='))
 1010 FORMAT(' Warning: lepton and nucleon momenta in same direction',
     &' not allowed.',/,10x,'Execution stopped.')
 1020 FORMAT(/,' JETSET version ',i3,'.',i3,' is used.',/,
     &' Parton densities in PYTHIA version ',i3,'.',i3,' are used.',/)
 1030   FORMAT(' Warning (LINIT): JETSET version before 7.402, MSTJ(46)'
     &  ,' set to',i4,/,18x,'to avoid mismatch LEPTO<-->LUSHOW.',/)
 1050 FORMAT(/,' User applied cuts (+ phase space) : ',1p,
     &      g12.4,' <   x   < ',g12.4,
     &/,37x,g12.4,' <   y   < ',g12.4,
     &/,37x,g12.4,' < Q**2  < ',g12.4,
     &/,37x,g12.4,' < W**2  < ',g12.4,
     &/,37x,g12.4,' <  nu   < ',g12.4,
     &/,37x,g12.4,' <  E''   < ',g12.4,
     &/,37x,g12.4,' < theta < ',g12.4,/,
     &/,       ' Effective ranges (from above cuts): ',
     &      g12.4,' <   x   < ',g12.4,
     &/,37x,g12.4,' <   y   < ',g12.4,
     &/,37x,g12.4,' < Q**2  < ',g12.4,
     &/,37x,g12.4,' < W**2  < ',g12.4,
     &/,37x,g12.4,' <  nu   < ',g12.4)
 1100 FORMAT(' Warning: effective upper limit of kinematical ',
     &'variable(s) smaller than corresponding lower limit.')
 1110 FORMAT(' Warning: lower limit in x and/or Q2 too small for ',
     &'DIS formalism.')
 1150 FORMAT(' Warning: weak charged current cross section zero for ',
     &'specified lepton helicity; LEPIN, PARL(6) =',i3,f5.2)
 1200 FORMAT(' Warning: unrecognized interaction in LINIT call: ',
     &'INTER = ',i5,'  for lepton LEPIN =',i5)
 1210 FORMAT(' Warning: unallowed value of LST(1) =',i3,
     &' and/or LST(31) =',i3)
 1220 FORMAT(/,' User-defined optimization parameters:',
     &/,5x,'OPTX(1...4)  =',4g11.3,/,5x,'OPTY(1...4)  =',4g11.3,
     &/,5x,'OPYQ2(1...4) =',4g11.3,/,5x,'OPTW2(1...4) =',4g11.3,/)
 1250 FORMAT(/,' Parameter values:', 
     &'LST(I+10)',8x,'PARL(I)',5x,'PARL(I+10)',1p,
     &/,5x,55('-'),10(/,3i10,2g15.4),/)
 1300 FORMAT(' Warning: cross section, PARL(23), excludes FL (see ',
     &'LST(11)) from:')
 1310 FORMAT(10x,'QCD, since evaluated event by event for LQCD=2')
 1320 FORMAT(10x,'TM , since evaluated event by event for LTM =2')
 1330 FORMAT(' Cross section in PARL(24) includes these contributions.')
 1400 FORMAT(' Max of differential cross section (for weighting) =',
     &e12.4,/,' obtained in ',f7.2,' seconds.',/)
 1500 FORMAT( 
     &'with those used when calculating QCD weights.', 
     &'current value     value for weights',/,
     &/,'     LST(12)   ',i12,10x,i12,
     &/,'     LST(13)   ',i12,10x,i12,
     &/,'     LST(15)   ',i12,10x,i12,
     &/,'     LST(16)   ',i12,10x,i12,
     &/,'     LST(17)   ',i12,10x,i12,
     &/,'     LST(23)   ',i12,10x,i12,
     &/,'     PARL(1)   ',e12.4,10x,e12.4,
     &/,'     PARL(2)   ',e12.4,10x,e12.4,
     &/,'     PARL(5)   ',e12.4,10x,e12.4,
     &/,'     PARL(6)   ',e12.4,10x,e12.4)
 1510 FORMAT(/,' Time for calculating QCD weights =',f5.1,' seconds',/)
 1900 FORMAT(' Execution stopped ',/)
      END