rdarry.F

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file rdarry.F

*72*********************************************************************
      subroutine rdarry(x,q2,aux,iflag)
      implicit real*8(a-h,o-z)
      implicit integer(i-n)
      data icount /0/
*
* to avoid variable conflictions, a second keep element is necessary
* with the same common block name (see LEPTO2)
*

      COMMON /leptou/ cut(14),lst(40),parl(30),
     &                xlp,ylp,w2lp,q2lp,ulp
      REAL cut,parl,xlp,ylp,w2lp,q2lp,ulp
      INTEGER lst
      SAVE /leptou/

      
      dimension aux(5)
      common/pdist/arraya(151,20,6)

      nx=151
      ndata=nx-1
      nq2pts=20
      nq2inv=nq2pts-1
      q2sta=1.d0
      q2fin=1.d6
      ymin=5.d0
      xmin=10.d0**(-ymin)
      xmax=1.d0

      if (q2.lt.q2sta) then
         q2=q2sta
         IF(cut(5).lt.q2.and.cut(6).gt.q2.AND.icount.lt.10) THEN
           icount = icount + 1
           WRITE(*,*) 'WARNING : rdarry : Q^2 set to minimal value !',q2
         ENDIF   
      endif
      if (q2.gt.q2fin) then
         q2=q2fin
         IF(cut(5).lt.q2.and.cut(6).gt.q2.AND.icount.lt.10) THEN
           icount = icount + 1
           WRITE(*,*) 'WARNING : rdarry : Q^2 set to maximal value !',q2
         ENDIF
      endif
      if (x.lt.xmin) then
         x=xmin
         IF(cut(1).lt.x.and.cut(2).gt.x.AND.icount.lt.10) THEN
           icount = icount + 1
           WRITE(*,*) 'WARNING : rdarry : X set to minimal value !',x
         ENDIF   
      endif
      if (x.gt.xmax) then
         x=xmax
         IF(cut(1).lt.x.and.cut(2).gt.x.AND.icount.lt.10) THEN
           icount = icount + 1
           WRITE(*,*) 'WARNING : rdarry : X set to maximal value !',x
         ENDIF         
      endif
      
      y=dlog10(x)
      ram=(y+ymin)*ndata/ymin+1.d0
      iram=int(ram)
      fraci=ram-dble(iram)
      ram=dlog(q2/q2sta)*nq2inv/dlog(q2fin/q2sta)+1.d0
      jram=int(ram)
      fracj=ram-dble(jram)
      
      do i=1,5
         aux(i)=(arraya(iram,jram,i)*(1.d0-fraci)
     .        +arraya(iram+1,jram,i)*fraci)*(1.d0-fracj)+
     .        (arraya(iram,jram+1,i)*(1.d0-fraci)
     .        +arraya(iram+1,jram+1,i)*fraci)*fracj
      enddo
      
      return
      end