dstfu.F

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file dstfu.F

************************************************************************
      SUBROUTINE dstfu(KF,X,Q2,XDPQ)

       IMPLICIT NONE

C...Gives proton and neutron structure functions according to a few
C...different polarized parametrizations.
C...Note that what is coded is x times the probability distribution,
C...i.e. xdq(x,Q2) etc.

*
* to avoid variable conflictions, a second keep element is necessary
* with the same common block name (see LEPTO2)
*

      COMMON /leptou/ cut(14),lst(40),parl(30),
     &                xlp,ylp,w2lp,q2lp,ulp
      REAL cut,parl,xlp,ylp,w2lp,q2lp,ulp
      INTEGER lst
      SAVE /leptou/

      COMMON /arstrf/ kfsave(2),xsave(2),xq2sav(2),
     +        xpqsav(2,-6:6),xdpqsav(2,-6:6)
      INTEGER kfsave
      REAL xsave,xq2sav,xpqsav,xdpqsav
      SAVE /arstrf/


      INTEGER kf,kfl,kfa
      REAL x,q2,xpq,xdpq,xdps
      dimension xpq(-6:6),xdpq(-6:6)

C...Reset structure functions.
      DO 100 kfl=-6,6
      xdpq(kfl)=0.
 100  xdpqsav(1,kfl)=0.
      xsave(1)=x
      xq2sav(1)=q2
      kfsave(1)=kf

C...Check x and particle species.
      IF(x.LE.0..OR.x.GE.1.) THEN
        WRITE(6,5000) x
        RETURN
      ENDIF
      kfa=iabs(kf)
      IF(kfa.NE.2112.AND.kfa.NE.2212) THEN
       WRITE(6,5100) kf
       RETURN
      ENDIF

*...  Put into output array  
      CALL parton(x,q2,xpq,xdpq)


C...Check positivity and reset above maximum allowed flavour.
      DO 180 kfl=-6,6
      IF(iabs(kfl).GT.lst(12)) THEN 
        xdpq(kfl)=0.
      ENDIF
 180  CONTINUE

C...  Isospin conjugation for neutron.
*HI>>      
      IF(kfa.EQ.2112.AND.lst(39).EQ.0) THEN
*     IF(KFA.EQ.2112) THEN
        xdps = xdpq(1)
        xdpq(1) = xdpq(2)
        xdpq(2) = xdps
        xdps = xdpq(-1)
        xdpq(-1) = xdpq(-2)
        xdpq(-2) = xdps
      ENDIF

C...Charge conjugation for antiparticle.
      IF(kf.LT.0) THEN
        DO 170 kfl=1,6
        xdps = xdpq(kfl)
        xdpq(kfl) = xdpq(-kfl)
        xdpq(-kfl) = xdps
  170   CONTINUE
      ENDIF

      DO 120 kfl=-6,6
  120 xdpqsav(1,kfl)=xdpq(kfl)

C...Formats for error printouts.
 5000 FORMAT(' Error: x value outside physical range; x =',1p,e12.3)
 5100 FORMAT(' Error: illegal particle code for structure function;',
     &' KF =',i5)
 5200 FORMAT(' Error: unknown structure function; KF, library, set =',
     &3i5)

      RETURN
      END