meix.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file meix.f

C+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
C++ Copyright S. Zhang and J. M. Jing                               ++
C++ Computation of Special Functions, John Wiley & Sons, New York,  ++
C++ 1996 and http://jin.ece.illinois.edu .                          ++
C+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
C
        SUBROUTINE eix(X,EI)
C
C       ============================================
C       Purpose: Compute exponential integral Ei(x)
C       Input :  x  --- Argument of Ei(x)
C       Output:  EI --- Ei(x) ( x > 0 )
C       ============================================
C
        IMPLICIT DOUBLE PRECISION (a-h,o-z)
        IF (x.EQ.0.0) THEN
           ei=-1.0d+300
        ELSE IF (x.LE.40.0) THEN
           ei=1.0d0
           r=1.0d0
           DO 15 k=1,100
              r=r*k*x/(k+1.0d0)**2
              ei=ei+r
              IF (dabs(r/ei).LE.1.0d-15) go to 20
15         CONTINUE
20         ga=0.5772156649015328d0
           ei=ga+dlog(x)+x*ei
        ELSE
           ei=1.0d0
           r=1.0d0
           DO 25 k=1,20
              r=r*k/x
25            ei=ei+r
           ei=dexp(x)/x*ei
        ENDIF
        RETURN
        END