rlu.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file rlu.f

    
C*********************************************************************  
    
      FUNCTION rlu(IDUM)    
    
C...Purpose: to generate random numbers uniformly distributed between   
C...0 and 1, excluding the endpoints.   
      common/ludatr/mrlu(6),rrlu(100)   
      SAVE /ludatr/ 
      equivalence(mrlu1,mrlu(1)),(mrlu2,mrlu(2)),(mrlu3,mrlu(3)),  
     &(mrlu4,mrlu(4)),(mrlu5,mrlu(5)),(mrlu6,mrlu(6)),  
     &(rrlu98,rrlu(98)),(rrlu99,rrlu(99)),(rrlu00,rrlu(100))    
    
C...Initialize generation from given seed.  
      IF(mrlu2.EQ.0) THEN   
        ij=mod(mrlu1/30082,31329)   
        kl=mod(mrlu1,30082) 
        i=mod(ij/177,177)+2 
        j=mod(ij,177)+2 
        k=mod(kl/169,178)+1 
        l=mod(kl,169)   
        DO 110 ii=1,97  
        s=0.    
        t=0.5   
        DO 100 jj=1,24  
        m=mod(mod(i*j,179)*k,179)   
        i=j 
        j=k 
        k=m 
        l=mod(53*l+1,169)   
        IF(mod(l*m,64).GE.32) s=s+t 
  100   t=0.5*t 
  110   rrlu(ii)=s  
        twom24=1.   
        DO 120 i24=1,24 
  120   twom24=0.5*twom24   
        rrlu98=362436.*twom24   
        rrlu99=7654321.*twom24  
        rrlu00=16777213.*twom24 
        mrlu2=1 
        mrlu3=0 
        mrlu4=97    
        mrlu5=33    
      ENDIF 
    
C...Generate next random number.    
  130 runi=rrlu(mrlu4)-rrlu(mrlu5)  
      IF(runi.LT.0.) runi=runi+1.   
      rrlu(mrlu4)=runi  
      mrlu4=mrlu4-1 
      IF(mrlu4.EQ.0) mrlu4=97   
      mrlu5=mrlu5-1 
      IF(mrlu5.EQ.0) mrlu5=97   
      rrlu98=rrlu98-rrlu99  
      IF(rrlu98.LT.0.) rrlu98=rrlu98+rrlu00 
      runi=runi-rrlu98  
      IF(runi.LT.0.) runi=runi+1.   
      IF(runi.LE.0.OR.runi.GE.1.) goto 130  
    
C...Update counters. Random number to output.   
      mrlu3=mrlu3+1 
      IF(mrlu3.EQ.1000000000) THEN  
        mrlu2=mrlu2+1   
        mrlu3=0 
      ENDIF 
      rlu=runi  
    
      RETURN    
      END