lscale.F

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file lscale.F

C **********************************************************************

      SUBROUTINE lscale(INFIN,QMAX)

      IMPLICIT NONE

C...Give maximum virtuality of partons in parton showers.

*
* to avoid variable conflictions, a second keep element is necessary
* with the same common block name (see LPTOU2)
*
      COMMON /leptou/ cut(14),lst(40),parl(30),
     &                x,y,w2,q2,u
      REAL cut,parl,x,y,w2,q2,u
      INTEGER lst
      SAVE /leptou/

      COMMON /pypara/ ipy(80),pypar(80),pyvar(80)
      REAL pypar,pyvar
      INTEGER ipy
      SAVE /pypara/ 

      INTEGER  nlupdm,nplbuf
      parameter(nlupdm=4000,nplbuf=5)
      common/lujets/n,k(nlupdm,5),p(nlupdm,nplbuf),v(nlupdm,5)
      INTEGER  n,k
      REAL  p,v
      SAVE /lujets/

C...  Power in f(x0)=(1-x0)**power used for scale x0*W2
      INTEGER infin,i,j
      REAL power,qmax,four,x0,rlu
      DATA power/3./
      four(i,j)=p(i,4)*p(j,4)-p(i,1)*p(j,1)-p(i,2)*p(j,2)-p(i,3)*p(j,3)

      qmax=0.1
      IF(lst(8).GE.2.AND.lst(8).LE.5) THEN
C...Parton showers without matrix elements matching
        IF(lst(9).EQ.1) THEN
          qmax=q2
        ELSEIF(lst(9).EQ.2) THEN
          qmax=w2
        ELSEIF(lst(9).EQ.3) THEN
          qmax=sqrt(w2*q2)
        ELSEIF(lst(9).EQ.4) THEN
          qmax=q2*(1.-x)
        ELSEIF(lst(9).EQ.5) THEN
          qmax=q2*(1.-x)*max(1.,log(1./max(1.e-06,x)))
        ELSEIF(lst(9).EQ.6) THEN
          x0=1.d0-(1.d0-dble(x))*rlu(0)**(1./(power+1.))
          qmax=x0*w2
        ELSEIF(lst(9).EQ.9) THEN
          qmax=w2**(2./3.)
        ELSE
          WRITE(6,*) ' Warning, LSCALE: LST(9)=',lst(9),' not allowed'
        ENDIF
      ELSEIF(lst(8).GT.10.AND.lst(24).EQ.1.AND.mod(lst(8),10).NE.9) THEN
C...Parton showers added to q-event from 1st order matrix elements
        IF(lst(20).LE.1) THEN
          qmax=parl(27)*w2
        ELSEIF(lst(20).EQ.2) THEN
          qmax=parl(27)*q2
        ELSEIF(lst(20).EQ.3) THEN
          qmax=parl(9)*q2
        ELSEIF(lst(20).EQ.4) THEN
          qmax=parl(9)*q2
          IF(infin.LT.0) qmax=parl(27)*q2/x
        ELSEIF(lst(20).EQ.5) THEN
          qmax=parl(9)
          IF(infin.LT.0) qmax=parl(27)*q2/x
        ELSEIF(lst(20).EQ.6) THEN
          qmax=parl(27)
          IF(infin.LT.0) qmax=parl(8)*q2/x
        ELSE
          WRITE(6,*) 'LSCALE: No such jet scheme!'
        ENDIF
      ELSEIF(lst(8).GT.10.AND.mod(lst(8),10).NE.9) THEN
C...Parton showers added to qg-/qqbar-event from 1st order matrix elements
C...Scale given by invariant mass of final parton pair
        qmax=p(27,5)**2
        IF(infin.LT.0)
     &  qmax=max(abs(-q2-2.*four(25,21)),abs(-q2-2.*four(26,21)))
      ENDIF
      qmax=sqrt(qmax)

      RETURN
      END