lyspli.F

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file lyspli.F

C **********************************************************************

      SUBROUTINE lyspli(KPART,KFLIN,KFLCH,KFLSP)

      IMPLICIT NONE

C...IN CASE OF A HADRON REMNANT WHICH IS MORE COMPLICATED THAN JUST A
C...QUARK OR A DIQUARK, SPLIT IT INTO TWO (PARTONS OR HADRON + PARTON).
*
* to avoid variable conflictions, a second keep element is necessary
* with the same common block name (see LPTOU2)
*
      COMMON /leptou/ cut(14),lst(40),parl(30),
     &                x,y,w2,q2,u
      REAL cut,parl,x,y,w2,q2,u
      INTEGER lst
      SAVE /leptou/

      
      INTEGER kpart,kflin,kflch,kflsp,iflin,ksign,ifl,idum
      REAL rlu,r
      
      iflin=kflin
      ksign=isign(1,kpart)
      ifl=kflin*ksign
      kflch=0
      idum=0

      IF(lst(14).EQ.0) THEN
C...If baryon production from remnant excluded, remnant is antiflavour
        kflsp=-kflin
        IF(kflin.EQ.21) kflsp=21
        RETURN
      ENDIF

      IF(iabs(kpart).EQ.211) THEN
C...DECOMPOSE PI+ (PI-).
        IF(ifl.EQ.2) THEN
C...VALENCE U (UBAR) REMOVED.
          kflsp=-1*ksign
        ELSEIF(ifl.EQ.-1) THEN
C...VALENCE D (DBAR) REMOVED.
          kflsp=2*ksign
        ELSEIF(kflin.EQ.21) THEN
C...GLUON REMOVED.
          r=2.*rlu(0)
          IF(r.LT.1.) THEN
            kflch=2*ksign
            kflsp=-1*ksign
          ELSE
            kflch=-1*ksign
            kflsp=2*ksign
          ENDIF
        ELSEIF((ifl.GE.1.AND.ifl.LE.8).AND.ifl.NE.2) THEN
C...SEA QUARK (ANTIQUARK) REMOVED.
          CALL lukfdi(-iflin,2*ksign,idum,kflch)
          kflsp=-1*ksign
        ELSEIF((ifl.GE.-8.AND.ifl.LE.-1).AND.ifl.NE.-1) THEN
C...SEA ANTIQUARK (QUARK) REMOVED.
          CALL lukfdi(-iflin,-1*ksign,idum,kflch)
          kflsp=2*ksign
        ENDIF

      ELSEIF(iabs(kpart).EQ.2212) THEN
C...DECOMPOSE PROTON (ANTIPROTON).
        IF(ifl.EQ.2) THEN
C...VALENCE U (UBAR) REMOVED.
          r=4.*rlu(0)
          IF(r.LT.3.) THEN
            kflsp=2101*ksign
          ELSE
            kflsp=2103*ksign
          ENDIF
        ELSEIF(ifl.EQ.1) THEN
C...VALENCE D (DBAR) REMOVED.
          kflsp=2203*ksign
        ELSEIF(kflin.EQ.21) THEN
C...GLUON REMOVED.
          r=6.*rlu(0)
          IF(r.LT.3.) THEN
            kflch=2*ksign
            kflsp=2101*ksign
          ELSEIF(r.LT.4.) THEN
            kflch=2*ksign
            kflsp=2103*ksign
          ELSE
            kflch=1*ksign
            kflsp=2203*ksign
          ENDIF
        ELSEIF(ifl.GT.2) THEN
C...SEA QUARK (ANTIQUARK) REMOVED.
          r=6*rlu(0)
          IF(r.LT.3.) THEN
            CALL lukfdi(-iflin,2*ksign,idum,kflch)
            kflsp=2101*ksign
          ELSEIF(r.LT.4.) THEN
            CALL lukfdi(-iflin,2*ksign,idum,kflch)
            kflsp=2103*ksign
          ELSE
            CALL lukfdi(-iflin,1*ksign,idum,kflch)
            kflsp=2203*ksign
          ENDIF
        ELSEIF(ifl.LT.0) THEN
C...SEA ANTIQUARK (QUARK) REMOVED.
  100     r=6*rlu(0)
          IF(r.LT.3.) THEN
            CALL lukfdi(2101*ksign,-iflin,idum,kflch)
            kflsp=2*ksign
          ELSEIF(r.LT.4.) THEN
            CALL lukfdi(2103*ksign,-iflin,idum,kflch)
            kflsp=2*ksign
          ELSE
            CALL lukfdi(2203*ksign,-iflin,idum,kflch)
            kflsp=1*ksign
          ENDIF
          IF(kflch.EQ.0) goto 100
        ENDIF

      ELSEIF(iabs(kpart).EQ.2112) THEN
C...DECOMPOSE NEUTRON (ANTINEUTRON).
        IF(ifl.EQ.2) THEN
C...VALENCE U (UBAR) REMOVED.
          kflsp=1103*ksign
        ELSEIF(ifl.EQ.1) THEN
C...VALENCE D (DBAR) REMOVED.
          r=4.*rlu(0)
          IF(r.LT.3.) THEN
            kflsp=2101*ksign
          ELSE
            kflsp=2103*ksign
          ENDIF
        ELSEIF(kflin.EQ.21) THEN
C...GLUON REMOVED.
          r=6.*rlu(0)
          IF(r.LT.2.) THEN
            kflch=2*ksign
            kflsp=1103*ksign
          ELSEIF(r.LT.5.) THEN
            kflch=1*ksign
            kflsp=2101*ksign
          ELSE
            kflch=1*ksign
            kflsp=2103*ksign
          ENDIF
        ELSEIF(ifl.GT.2) THEN
C...SEA QUARK (ANTIQUARK) REMOVED.
          r=6*rlu(0)
          IF(r.LT.2.) THEN
            CALL lukfdi(-iflin,2*ksign,idum,kflch)
            kflsp=1103*ksign
          ELSEIF(r.LT.5.) THEN
            CALL lukfdi(-iflin,1*ksign,idum,kflch)
            kflsp=2101*ksign
          ELSE
            CALL lukfdi(-iflin,1*ksign,idum,kflch)
            kflsp=2103*ksign
          ENDIF
        ELSEIF(ifl.LT.0) THEN
C...SEA ANTIQUARK (QUARK) REMOVED.
  110     r=6*rlu(0)
          IF(r.LT.2.) THEN
            CALL lukfdi(1103*ksign,-iflin,idum,kflch)
            kflsp=2*ksign
          ELSEIF(r.LT.5.) THEN
            CALL lukfdi(2101*ksign,-iflin,idum,kflch)
            kflsp=1*ksign
          ELSE
            CALL lukfdi(2103*ksign,-iflin,idum,kflch)
            kflsp=1*ksign
          ENDIF
          IF(kflch.EQ.0) goto 110
        ENDIF
      ENDIF

      RETURN
      END