luerrm.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file luerrm.f

    
C*********************************************************************  
    
      SUBROUTINE luerrm(MERR,CHMESS)    
    
C...Purpose: to inform user of errors in program execution. 
      common/lujets/n,k(9000,5),p(9000,5),v(9000,5)
      SAVE /lujets/ 
      common/ludat1/mstu(200),paru(200),mstj(200),parj(200) 
      SAVE /ludat1/ 
      CHARACTER chmess*(*)  
    
C...Write first few warnings, then be silent.   
      IF(merr.LE.10) THEN   
        mstu(27)=mstu(27)+1 
        mstu(28)=merr   
        IF(mstu(25).EQ.1.AND.mstu(27).LE.mstu(26)) WRITE(mstu(11),1000) 
     &  merr,mstu(31),chmess    
    
C...Write first few errors, then be silent or stop program. 
      ELSEIF(merr.LE.20) THEN   
        mstu(23)=mstu(23)+1 
        mstu(24)=merr-10    
        IF(mstu(21).GE.1.AND.mstu(23).LE.mstu(22)) WRITE(mstu(11),1100) 
     &  merr-10,mstu(31),chmess 
        IF(mstu(21).GE.2.AND.mstu(23).GT.mstu(22)) THEN 
          WRITE(mstu(11),1100) merr-10,mstu(31),chmess  
          WRITE(mstu(11),1200)  
          IF(merr.NE.17) CALL lulist(2) 
          stop  
        ENDIF   
    
C...Stop program in case of irreparable error.  
      ELSE  
        WRITE(mstu(11),1300) merr-20,mstu(31),chmess    
        stop    
      ENDIF 
    
C...Formats for output. 
 1000 FORMAT(/5x,'Advisory warning type',i2,' given after',i6,  
     &' LUEXEC calls:'/5x,a)    
 1100 FORMAT(/5x,'Error type',i2,' has occured after',i6,   
     &' LUEXEC calls:'/5x,a)    
 1200 FORMAT(5x,'Execution will be stopped after listing of last ', 
     &'event!') 
 1300 FORMAT(/5x,'Fatal error type',i2,' has occured after',i6, 
     &' LUEXEC calls:'/5x,a/5x,'Execution will now be stopped!')    
    
      RETURN    
      END